prologues := 3;
input boxes

beginfig(1);
arrowlenx=16mm; arrowleny=10mm;
dasheslen = 6mm; dashesgap = 3mm;
textscale=1.5;
pickup pencircle scaled 1pt;
circleit.xa(btex $x(t-1)$ etex scaled textscale);
circleit.xb(btex $x(t)$ etex scaled textscale);
circleit.xc(btex $x(t+1)$ etex scaled textscale);
circleit.ya(btex $y(t-1)$ etex scaled textscale);
circleit.yb(btex $y(t)$ etex scaled textscale);
circleit.yc(btex $y(t+1)$ etex scaled textscale);
xa.dx = xb.dx = xc.dx = ya.dx = yb.dx = yc.dx = defaultdx*4;
xa.dy = xb.dy = xc.dy = ya.dy = yb.dy = yc.dy = defaultdy*4;
xpart xa.w = dasheslen + arrowlenx;
ypart ya.s = ypart yb.s = ypart yc.s = 0;
xb.w = xa.e + (arrowlenx,0);
xc.w = xb.e + (arrowlenx,0);
xa.s = ya.n + (0,arrowleny);
xpart xb.s = xpart yb.n;
xpart xc.s = xpart yc.n;
drawboxed(xa, xb, xc, ya, yb, yc);
z1 = xa.w - (arrowlenx,0);
drawarrow xa.e--xb.w;
drawarrow xb.e--xc.w;
z2 = xc.e + (arrowlenx,0);
drawarrow xa.s--ya.n;
drawarrow xb.s--yb.n;
drawarrow xc.s--yc.n;
linecap := butt;
drawarrow (z1 + (dashesgap,0))--xa.w;
drawarrow xc.e--(z2 - (dashesgap,0));
draw (z1 - (dasheslen,0))--z1 dashed evenly;
draw z2--(z2 + (dasheslen,0)) dashed evenly;
endfig;
end